Kazuho@Cybozu Labs

　ちなみに、Perl で複数個のワーカープロセスを動かして処理を行う場合のコードは、以下のような感じになるでしょう。Apache の prefork モデルを単純化した形と言うこともできます。デーモン (特にサーバ) を書く場合には、頻出のコーディングパターンかな、と思います。

#! /usr/bin/perl

use strict;
use warnings;

use Proc::Wait3;

my %worker_pids;
my $num_workers = 4; # ワーカープロセスの数
my $exit_loop;

# サーバの初期化処理
...

# SIGTERM ハンドラをセット
$SIG{TERM} = sub { $exit_loop = 1 };

# メインループ ($num_workers 個のワーカープロセスを駆動)
while (! $exit_loop) {
    my $pid;
    if (keys %worker_pids < $num_workers) {
        $pid = fork;
        die 'fork error' unless defined $pid;
        if ($pid) {
            $worker_pids{$pid} = 1;
        } else {
            exit(child());
        }
        sleep 1;
    }
    if (my ($exit_pid) = wait3(! $pid)) {
        delete $worker_pids{$exit_pid};
    }
}
# ワーカーを停止して終了
foreach my $c (keys %worker_pids) {
    kill 'TERM', $c;
}
while (%worker_pids) {
    if (my $exit_pid = wait) {
        delete $worker_pids{$exit_pid};
    }
}
exit 0;

# ワーカープロセス
sub child {
    # SIGTERM ハンドラをセット
    $SIG{TERM} = sub { exit 0 };
    # 実際の処理
    ...
    # 終了コードを返す
    0;
}

　ちなみに、わざわざ Proc::Wait3 を使っているのは、perl の wait や waitpid だとシグナルを受け取っても制御が返ってこないためです。今回改めて調べてみて、この事実にたどり着きました。なんともバッドノウハウです。